***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 08, 2023                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ4403EP-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs     s1    s2   205u TC=2m
Rg     g1    g2     11.5
M1     d2     g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS PMOS ( KP=45.8  VTO=-2.05  THETA=0  VMAX=1.5e5  ETA=0  LEVEL=3  GAMMA=1.5)
Rd     d1    d2    9.82m  TC=3m
Dbd    d2    s2    Dbt
.MODEL     Dbt    D(BV=33  TBV1=8.1e-4  M=0.523  CJO=0.564n  VJ=0.39V)
Dbody   21   s2    DBODY
.MODEL DBODY  D(IS=22p  N=1.10  RS=0.04u  EG=1.10  TT=30n)
Rdiode  d1  21    8.25m  TC=1.5m
.MODEL   sw    PMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   0.598n
.MODEL     DGD    D(M=0.355  CJO=0.598n  VJ=0.39)
Rpar      b    d2   1Meg
Dgd       d2    a   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    1.46n
.ENDS
*$
